Creation of Public Housing from Existing Housing Units/Longitudinal Matching of Housing Units

3 posts / 0 new
Last post
matthew_lapenta...
Offline
Last seen: 1 month 1 week ago
Joined: 09/07/2017 - 16:34
Creation of Public Housing from Existing Housing Units/Longitudinal Matching of Housing Units

I am hoping someone can help me understand an unexpected result I am getting using the 2011 and 2013 national American Housing Survey (AHS) datasets. I was trying to figure out the share of public housing in 2013 that was converted to public housing from being private housing in 2011. I don't think this is common these days, so I was expecting it to be very small or even unobserved.

So I first created a dataset that had only the 2013 AHS public housing units and joined it with the 2011 AHS data so that I had a new data set comprised of housing units that were both public housing units in 2013 and included in the 2011 data. I used the "CONTROL" variable to join the 2011 and 2013 data and used the "HUDADMIN" variable to identify public housing. 20% of the 2013 public housing units were not identified as public housing units in 2011 (ignoring weights).

This seems way too high based on what I have read about trends in public housing. The "HUDADMIN" variable is created using HUD administrative records, so I don't think the problem can be respondent reporting errors. Any explanations for why I am getting this result would be appreciated.

The SAS code I used is below. Thanks!

-Matt

*Author: Matthew LaPenta;
*Creation Date: 07SEP17
*Description: Estimate the percentage of public housing units in the 2013 data that were not public housing units
in the 2011 data (excluding newly constructed units);
*Inputs:
ahs2013n (2013 national AHS flat file)
ahs2011n (2011 national AHS flat file);

*define input libary;
libname inputs "../inputs";

*Get 2013 data and keep only relevant variables;
data d01_2013 (keep=control Proj2013 weight2013);
set inputs.ahs2013n;
*rename weight so that it is survey year-specific;
rename weight=weight2013;

*HUDADMIN Response Codes:
1: Yes, public housing
2: Yes, someone in unit received a voucher
3: Yes, privately owned subsidized housing
4: Unit did not receive any type of government rental assistance
B or -6: Not applicable;
*Define 2013 binary variable for public housing;
if hudadmin=1 then Proj2013="Yes"; else Proj2013="No";
run;

*Get 2011 data and keep only relevant variables;
data d01_2011 (keep=control Proj2011 weight2011);
set inputs.ahs2011n;
*rename weight so that it is survey year-specific;
rename weight=weight2011;
*Note: HUDADMIN Response Codes:
1: Yes, public housing
2: Yes, someone in unit received a voucher
3: Yes, privately owned subsidized housing
4: Unit did not receive any type of government rental assistance
B or -6: Not applicable;
*Define 2011 binary variable for public housing;
if hudadmin=1 then Proj2011="Yes"; else Proj2011="No";
run;

*Perform inner join on 2011 and 2013 data, dropping housing units that are not in both samples;
proc sql;
create table d02 as select
d11.control,
proj2013,
proj2011,
weight2013
from d01_2013 d13 inner join d01_2011 d11 on d11.control=d13.control;
quit;

*Get counts and populations of units according to public housing status;
proc sql;
create table d03 as select
proj2011,
proj2013,
count(control) as count format=comma20.0,
sum(weight2013) as housingunits format=comma20.0
from d02 group by Proj2011, proj2013;
quit;

*Calculate percentages for counts and populations of units according to public housing status;
proc sql;
create table d04 as select
proj2011,
proj2013,
count/sum(count) as countpercent format=percent10.0 label="Unweighted Percentage of Housing Units",
housingunits/sum(housingunits) as HUspercent format=percent10.0 label="Weighted Percentage of Housing Units"
from d03 where proj2013="Yes";
quit;

Dav Vandenbroucke
Offline
Last seen: 1 month 1 week ago
Joined: 02/02/2010 - 11:48
Thank you for bringing this

Thank you for bringing this to our attention. We will take a look at the data and get back to you.

Dav Vandenbroucke
Senior Economist
Office of Policy Development & Research

Dav Vandenbroucke
Offline
Last seen: 1 month 1 week ago
Joined: 02/02/2010 - 11:48
Improved HUDADMIN match

We have improved our address matching procedure and will be releasing a new version of HUDADMIN soon. If you contact me at david.a.vandenbroucke@hud.gov, I can send you a skinny file with the improved variable, which shows fewer mismatches than the version in the current PUF.

The AHS sample includes an oversample of addresses drawn from HUD administrative records (and thus known to be assisted). The oversample cases are identified by HUDSAMP=1. If you crosstabulate your results with HUDSAMP, you will see that almost all of the mismatched cases are from the general sample, not the oversample. This is evidence that the address matching process still needs work. The weighted results are more skewed than the unweighted because general sample cases have higher weights than oversample.

Dav Vandenbroucke
Senior Economist
Office of Policy Development & Research
david.a.vandenbroucke@hud.gov

Disclaimer : All messages made available as part of this forum, including opinions, advice, statements or other information contained in any messages posted or transmitted by any third party are the responsibility of the author of that message and do not necessarily reflect the views and policies of HUD or the U.S. Government. HUD cannot attest to the accuracy, completeness or usefulness of any messages. This is a monitored forum; posts are subject to approval.